***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Apr 04, 2025                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the data sheet for specification limits.                             *
***********************************************************************
*$
.subckt   PJB160P04E-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2   205u TC=3m
Rg     g1    g2     2.956
M1     d2     g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS PMOS ( KP=312.8  VTO=-2.54  THETA=0  VMAX=1.2e11  ETA=0  LEVEL=3  GAMMA=1.60  nfs=7.27305e11)
Rd     d1    d2    2.8m TC=4.8m,10u
Dbd    d2    s2    Dbt
.MODEL     Dbt    D(BV=44 TBV1=8.625e-4 TBV2=-4.205e-7   CJO=1.760e-9   M=5.002e-1   VJ=2.949e-1)
Dbody   21   s2    DBODY
.MODEL DBODY  D(IS=1.282e-14   N=7.790e-1  RS=4e-8  EG=1.100  TT=30n  ikf=1.537  ;tikf=7.361e-3)
Rdiode  d1  21    1.886e-3  TC=1.0m
.MODEL   sw    PMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   3.644e-9
.MODEL     DGD    D(CJO=3.644e-9 M=3.899e-1  VJ=3.449e-1)
Rpar      b    d2   1Meg
Dgd       d2    a   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    6.459e-9
.ENDS PJB160P04E-AU
*$
